Working with Intercompany Insights

This article describes how to extend functionality using custom extension.

Events

codeunit 20020851 "ITI ICI Management"

OnBeforeInsertAvailabilityLine(var ITIICIAvailability: Record "ITI ICI Availability"; JsonObj: JsonObject)

This event is triggered when a response with availability data has been received. It occurs just before inserting the availability entry. It can be used to copy any additional fields from the json response.

Fields are placed in the json objects using names from the page 20020852 "ITI ICI Availability WS". Spaces replaced by underscores and dots are removed, for example Item No. becomes Item_No.

OnBeforeInsertCustomerBalanceLine(var ITIICICustomerBalance: Record "ITI ICI Customer Balance"; JsonObj: JsonObject)

This event is triggered when a response with customer data has been received. It occurs just before inserting the customer balance entry. It can be used to copy any additional fields from the json response.

Fields are placed in the json objects using names from the page 20020852 "ITI ICI Availability WS". Spaces replaced by underscores and dots are removed.

OnBeforeInsertCustomerBalanceDetailLine(var ITIICICustLEntryBuffer: Record "ITI ICI Cust. L. Entry Buffer"; JsonObj: JsonObject)

This event is triggered when a response with customer details data has been received. It occurs just before inserting the temporary customer ledger entry. It can be used to copy any additional fields from the json response.

Fields are placed in the json objects using names from the page 20020858 "ITI ICI Cust. Ledger Entry WS". Spaces replaced by underscores and dots are removed, for example Document No. becomes Document_No.

codeunit 20020852 "ITI ICI Sender Mgt."

OnCreateAvailabilityLine(var Item: Record Item; var ITIICIAvailability: Record "ITI ICI Availability" temporary)

This event is triggered, when a request for availability data is received and a response is being built. It occurs for each of the item, variant and location combination that matches filters (items and variants) and setup (locations).

It can be used to fill any additional fields in the buffer. Item is passed as VAR to keep location and variant filters, so CalcFields can be called. Fields should be filled using a += operator instead of :=, to comply also with the sum of all locations scenario.

OnCreateCustomerBalanceLine(Customer: Record Customer; var ITIICICustomerBalance: Record "ITI ICI Customer Balance" temporary)

This event is triggered, when a request for customer data is received and a response is being built. It occurs for each customer that matches the filter.

It can be used to fill any additional fields in the buffer.

Example

Table extension

New fields need to be added to the extended table.

tableextension 50149 "ITIICIAvailability" extends "ITI ICI Availability"
{
    fields
    {
        field(50149; "Description"; Text[100])
        {
        }
        field(50148; "Sales (Qty.)"; Decimal)
        {
        }
    }
}

Page extensions

New fields need to be added to the WS page. If they should be visible on availability overview then can also be added to the overview page. In the WS page its recommended to not use spaces or dots in field names, so the same will be present in json object.

pageextension 50148 MyExtension2 extends "ITI ICI Availability WS"
{
    layout
    {
        addlast(Group)
        {
            field(Description; "Description")
            {
                ApplicationArea = All;
            }
            field(SalesQty; "Sales (Qty.)")
            {
                ApplicationArea = All;
            }
        }
    }
}


pageextension 50149 MyExtension extends "ITI ICI Availability Overview"
{
    layout
    {
        addlast(Group)
        {
            field(Description; "Description")
            {
                ApplicationArea = All;
            }
            field(SalesQty; "Sales (Qty.)")
            {
                ApplicationArea = All;
            }
        }
    }
}

Adding data to buffer

Any data needs to be calcualted and added to buffer.

    [EventSubscriber(ObjectType::Codeunit, Codeunit::"ITI ICI Sender Mgt.", 'OnCreateAvailabilityLine', '', false, false)]
    local procedure MyProcedure(var Item: Record Item; var ITIICIAvailability: Record "ITI ICI Availability")
    begin
        Item.CalcFields("Sales (Qty.)");
        ITIICIAvailability."Sales (Qty.)" += Item."Sales (Qty.)";
        ITIICIAvailability."Description" := item.Description;
    end;

Reading data from json

The values needs to be retrieved from json objects, read as correct types and assigned to desired fields.

    [EventSubscriber(ObjectType::Codeunit, Codeunit::"ITI ICI Management", 'OnBeforeInsertAvailabilityLine', '', false, false)]
    local procedure MyProcedure2(JsonObj: JsonObject; var ITIICIAvailability: Record "ITI ICI Availability")
    var
        jsonTok: JsonToken;
    begin
        JsonObj.Get('Description', jsonTok);
        ITIICIAvailability."Description" := jsonTok.AsValue().AsText();
        JsonObj.Get('SalesQty', jsonTok);
        ITIICIAvailability."Sales (Qty.)" := jsonTok.AsValue().AsDecimal();
    end;

Customer balances

The customer balance overview process can be modified in similar way as the item availability above.

Customer details web service page is based on the customer ledger entry table, so no code is needed to add new field to the response - it is enough to add it to the page. The code is needed only to read data from json object.